---
title: "表达式语法 - OceanBase 数据库 V4.2.1 | OceanBase 文档中心"
description: "表达式语法 本节列出了表达式必须遵循的语法规则。 以下语法规则定义了 OceanBase 数据库的表达式语法： expr: expr AND expr | expr && expr | expr OR expr | expr || expr | expr XOR expr | NOT expr | bool_pri …"
image: https://mdn.alipayobjects.com/huamei_22khvb/afts/img/A*OSPzQ6GUQF4AAAAAQHAAAAgAeiGDAQ/original
---
切换语言

- 中文站 - 简体中文
- International - English
- 日本站 - 日本語

文档反馈![](https://mdn.alipayobjects.com/huamei_22khvb/afts/img/A*P8CuR4UJ_FkAAAAAAAAAAAAADiGDAQ/original) OceanBase 数据库分布式版 - V 4.2.1 LTS

# 表达式语法

更新时间：2026-07-15 20:56:55

[编辑](https://github.com/oceanbase/oceanbase-doc/edit/V4.2.1/zh-CN/700.reference/500.sql-reference/100.sql-syntax/200.common-tenant-of-mysql-mode/100.basic-elements-of-mysql-mode/200.expression-of-mysql-mode/200.expression-syntax-of-mysql-mode.md)  

本节列出了表达式必须遵循的语法规则。

以下语法规则定义了 OceanBase 数据库的表达式语法：

```sql
expr:
expr AND expr
| expr && expr
| expr OR expr
| expr || expr
| expr XOR expr
| NOT expr
| bool_pri IS BOOL_VALUE
| bool_pri IS not BOOL_VALUE
| bool_pri IS UNKNOWN
| bool_pri IS not UNKNOWN
| bool_pri := expr
;

bool_pri:
bool_pri IS NULL
| bool_pri IS not NULL
| bool_pri COMP_LE predicate
| bool_pri COMP_LE sub_query_flag '(' select_no_parens ')'
| bool_pri COMP_LT predicate
| bool_pri COMP_LT sub_query_flag '(' select_no_parens ')'
| bool_pri COMP_EQ predicate
| bool_pri COMP_EQ sub_query_flag '(' select_no_parens ')'
| bool_pri COMP_NSEQ predicate
| bool_pri COMP_GE predicate
| bool_pri COMP_GE sub_query_flag '(' select_no_parens ')'
| bool_pri COMP_GT predicate
| bool_pri COMP_GT sub_query_flag '(' select_no_parens ')'
| bool_pri COMP_NE predicate
| bool_pri COMP_NE sub_query_flag '(' select_no_parens ')'
| predicate
;

comparison_operator:
COMP_LE ==> '<='
COMP_LT ==> '<'
COMP_EQ ==> '='
COMP_NSEQ ==> '<=>'
COMP_GE ==> '>='
COMP_GT ==> '>'
COMP_NE ==> '!='

predicate:
bit_expr IN in_expr
| bit_expr not IN in_expr
| bit_expr not BETWEEN bit_expr AND predicate
| bit_expr BETWEEN bit_expr AND predicate
| bit_expr LIKE simple_expr
| bit_expr LIKE simple_expr ESCAPE simple_expr
| bit_expr not LIKE simple_expr
| bit_expr not LIKE simple_expr ESCAPE simple_expr
| bit_expr REGEXP bit_expr
| bit_expr not REGEXP bit_expr
| bit_expr
;

bit_expr:
bit_expr '|' bit_expr
| bit_expr '&' bit_expr
| bit_expr << bit_expr
| bit_expr >> bit_expr
| bit_expr '+' bit_expr
| bit_expr '-' bit_expr
| bit_expr '+' INTERVAL expr date_unit
| bit_expr '-' INTERVAL expr date_unit
| bit_expr '*' bit_expr
| bit_expr '/' bit_expr
| bit_expr '%' bit_expr
| bit_expr MOD bit_expr
| bit_expr DIV bit_expr
| bit_expr '^' bit_expr
| simple_expr
;

simple_expr:
simple_expr collation
| BINARY simple_expr
| column_ref
| expr_const
| simple_expr CNNOP simple_expr
| '+' simple_expr
| '-' simple_expr
| '~' simple_expr
| '!' simple_expr
| not simple_expr
| select_with_parens
| '(' expr ')'
| '(' expr_list ',' expr ')'
| ROW '(' expr_list ',' expr ')'
| EXISTS select_with_parens
| MATCH '(' column_list ')' AGAINST '(' STRING_VALUE opt_mode_flag ')'
| case_expr
| func_expr
| window_function
| USER_VARIABLE
;

```

有关运算符优先级，请参见 [运算符优先级](https://www.oceanbase.com/docs/common-oceanbase-database-cn-1000000000221455)。

 上一篇 下一篇 ![有帮助](https://gw.alipayobjects.com/mdn/ob_asset/afts/img/A*y6ocSqN8cqsAAAAAAAAAAAAAARQnAQ)![无帮助](https://gw.alipayobjects.com/mdn/ob_asset/afts/img/A*BG9IQJyLHF8AAAAAAAAAAAAAARQnAQ)![反馈](https://gw.alipayobjects.com/mdn/ob_asset/afts/img/A*eTWdQKCRKHwAAAAAAAAAAAAAARQnAQ)[AI](https://www.oceanbase.com/obi) 咨询热线